home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / RESISTIV.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1996-09-28  |  2.7 KB  |  106 lines
  1. 10  'RESISTIV - Resistivity of Metals - 19 JAN 96 rev. 28 SEP 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  CLS:KEY OFF
  4. 40  COLOR 7,0,1
  5. 50  DIM M$(18,2)
  6. 60  U$="###.###"
  7. 70  UL$=STRING$(80,205)
  8. 80  E$=STRING$(80,32)
  9. 90  GOTO 190
  10. 100  '
  11. 110  DATA ALUMINUM (pure), BRASS (most conductive alloy)
  12. 120  DATA BRASS (least conductive alloy), CADMIUM, CHROMIUM, COPPER (hard-drawn)
  13. 130  DATA COPPER (annealed), GOLD, IRON (pure), LEAD, NICKEL
  14. 140  DATA PHOSPHOR BRONZE (most conductive alloy)
  15. 150  DATA PHOSPHOR BRONZE (least conductive alloy)
  16. 160  DATA SILVER, STEEL (most conductive alloy), STEEL (least conductive alloy)
  17. 170  DATA TIN, ZINC
  18. 180  '
  19. 190  FOR Z=1 TO 18:READ M$(Z,1):NEXT Z
  20. 200  DATA 1.6, 3.7, 4.9, 4.4, 1.8, 1.03, 1.00, 1.4, 5.68, 12.8, 5.1, 2.8, 5.4
  21. 210  DATA 0.94, 7.6, 12.7, 6.7, 3.4
  22. 220  FOR Z=1 TO 18:READ M$(Z,2):NEXT Z
  23. 230  '
  24. 240  '.....start
  25. 250  CLS
  26. 260  COLOR 15,2
  27. 270  PRINT " RESISTIVITY OF METALS";TAB(57)"by George Murphy VE3ERP ";
  28. 280  COLOR 1,0:PRINT STRING$(80,223);
  29. 290  COLOR 7,0
  30. 300  '
  31. 310  GOSUB 840    'preface
  32. 320  PRINT UL$;
  33. 330  LOCATE CSRLIN,21
  34. 340  COLOR 0,7:PRINT " Press 1 to continue or 0 to EXIT......":COLOR 7,0
  35. 350  Q$=INKEY$:IF Q$=""THEN 350
  36. 360  IF Q$="0"THEN CLS:RUN EX$
  37. 370  IF Q$="1"THEN 400
  38. 380  GOTO 350
  39. 390  '
  40. 400  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  41. 410  COLOR 0,7
  42. 420  PRINT " Press a letter in < > to select a Reference Base:"
  43. 430  COLOR 7,0
  44. 440  ROW=5
  45. 450  LOCATE ROW:PRINT UL$;
  46. 460   FOR Z=1 TO 18:PRINT " < ";CHR$(96+Z);" >";
  47. 470    LOCATE CSRLIN,9:PRINT M$(Z,1);
  48. 480  IF Z=6 THEN PRINT " e.g. some types of antenna wire":GOTO 510
  49. 490  IF Z=7 THEN PRINT " e.g. most electrical wiring":GOTO 510
  50. 500  PRINT ""
  51. 510   NEXT Z
  52. 520  '
  53. 530  Z$=INKEY$:IF Z$=""THEN 530
  54. 540  Y=ASC(Z$):IF Y<97 OR Y>114 THEN 530
  55. 550  VIEW PRINT 3 TO 4:CLS:VIEW PRINT:LOCATE 3
  56. 560  Y=Y-96
  57. 570  PRINT TAB(8)" Relative Resistivity Factors for Various Metals,"
  58. 580  PRINT TAB(8)" compared to";
  59. 590  COLOR 0,7:PRINT " ";M$(Y,1);" "
  60. 600  COLOR 7,0
  61. 610  W=VAL(M$(Y,2))
  62. 620   FOR Z=ROW+1 TO ROW+18
  63. 630    LOCATE Z,1:PRINT "      "
  64. 640    X=LEN(M$(Z-ROW,1))
  65. 650    LOCATE Z,9+X:PRINT STRING$(46-X,".")
  66. 660    IF Z=ROW+Y THEN COLOR 0,7 ELSE COLOR 7,0
  67. 670    LOCATE Z,53:PRINT USING U$;VAL(M$(Z-ROW,2))/W
  68. 680    COLOR 7,0
  69. 690    GOSUB 750
  70. 700   NEXT Z
  71. 710  LOCATE ROW+Y,8:COLOR 0,7:PRINT " "+M$(Y,1)+" ";
  72. 720  COLOR 7,0
  73. 730  GOTO 790
  74. 740  '
  75. 750  IF Z=ROW+ 9 THEN LOCATE ,61:PRINT "(highest resistance)"
  76. 760  IF Z=ROW+13 THEN LOCATE ,61:PRINT "(lowest resistance)"
  77. 770  RETURN
  78. 780  '
  79. 790  '.....end
  80. 800  GOSUB 920
  81. 810  GOTO 240
  82. 820  END
  83. 830  '
  84. 840  '.....preface
  85. 850  T=7
  86. 860  PRINT TAB(T);
  87. 870  PRINT "This programs computes the relative resistivity of various metals"
  88. 880  PRINT TAB(T);
  89. 890  PRINT "compared to a base reference metal of your choice."
  90. 900  RETURN
  91. 910  '
  92. 920  '.....HARDCOPY - revised from SCREEN DUMP 08 APR 95 - 27 SEP 96
  93. 930  VIEW PRINT:GOSUB 1050:LOCATE 25,2:COLOR 14,6
  94. 940  PRINT " Press 1 to print screen, 2 to print screen & ";
  95. 950  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  96. 960  Z$=INKEY$:IF Z$="3"THEN GOSUB 1050:GOTO 1040
  97. 970  IF Z$="1"OR Z$="2"THEN GOSUB 1050:GOTO 990
  98. 980  GOTO 960
  99. 990   FOR QX=1 TO 24:FOR QY=1 TO 80       '24 lines x 80 characters
  100. 1000    LPRINT CHR$(SCREEN(QX,QY));        'print ASCII character
  101. 1010   NEXT QY:NEXT QX
  102. 1020  IF Z$="2"THEN LPRINT CHR$(12)        'form feed
  103. 1030  GOTO 930
  104. 1040  RETURN
  105. 1050  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  106.